[FFmpeg-devel] [PATCH 1/7] x86: sbrdsp: implement SSE/SSE2 qmf_pre_shuffle

[Christophe Gisquet]

>From 253 to 70(sse)/52(sse2) cycles on Arrandale and Win64.
61/55 cycles on SandyBridge.
---
 libavcodec/x86/sbrdsp.asm    | 54 ++++++++++++++++++++++++++++++++++++++++++++
 libavcodec/x86/sbrdsp_init.c |  7 ++++++
 2 files changed, 61 insertions(+)

diff --git a/libavcodec/x86/sbrdsp.asm b/libavcodec/x86/sbrdsp.asm
index 999e5af..f3c30d0 100644
--- a/libavcodec/x86/sbrdsp.asm
+++ b/libavcodec/x86/sbrdsp.asm
@@ -242,3 +242,57 @@ cglobal sbr_neg_odd_64, 1,2,4,z
     cmp        zq, r1q
     jne     .loop
     REP_RET
+
+%macro SBR_QMF_PRE_SHUFFLE 0
+cglobal sbr_qmf_pre_shuffle, 1,4,7,z
+%define OFFSET  (32*4-2*mmsize)
+    mov       r3q, OFFSET
+    lea       r1q, [zq + (32+1)*4]
+    lea       r2q, [zq + 64*4]
+    mova       m6, [ps_neg]
+.loop:
+    movu       m0, [r1q]
+    movu       m2, [r1q + mmsize]
+    movu       m1, [zq + r3q + 4 + mmsize]
+    movu       m3, [zq + r3q + 4]
+%if cpuflag(sse2)
+%define XOR      pxor
+%define SHUFFLE  pshufd
+%define UNPACKL  punpckldq
+%define UNPACKH  punpckhdq
+%define MOVH     movq
+%else
+%define XOR      xorps
+%define SHUFFLE  shufps
+%define UNPACKL  unpcklps
+%define UNPACKH  unpckhps
+%define MOVH     movlps
+%endif
+
+    XOR        m2, m6
+    XOR        m0, m6
+    SHUFFLE    m2, m2, q0123
+    SHUFFLE    m0, m0, q0123
+    mova       m5, m2
+    mova       m4, m0
+    UNPACKL    m2, m3
+    UNPACKH    m5, m3
+    UNPACKL    m0, m1
+    UNPACKH    m4, m1
+    mova  [r2q + 2*r3q + 0*mmsize], m2
+    mova  [r2q + 2*r3q + 1*mmsize], m5
+    mova  [r2q + 2*r3q + 2*mmsize], m0
+    mova  [r2q + 2*r3q + 3*mmsize], m4
+    add       r1q, 2*mmsize
+    sub       r3q, 2*mmsize
+    jge      .loop
+    mova       m2, [zq]
+    MOVH    [r2q], m2
+    REP_RET
+%endmacro
+
+INIT_XMM sse
+SBR_QMF_PRE_SHUFFLE
+
+INIT_XMM sse2
+SBR_QMF_PRE_SHUFFLE
diff --git a/libavcodec/x86/sbrdsp_init.c b/libavcodec/x86/sbrdsp_init.c
index d8d6ae7..5311a24 100644
--- a/libavcodec/x86/sbrdsp_init.c
+++ b/libavcodec/x86/sbrdsp_init.c
@@ -34,6 +34,8 @@ void ff_sbr_hf_gen_sse(float (*X_high)[2], const float (*X_low)[2],
                        float bw, int start, int end);
 void ff_sbr_qmf_post_shuffle_sse(float W[32][2], const float *z);
 void ff_sbr_neg_odd_64_sse(float *z);
+void ff_sbr_qmf_pre_shuffle_sse(float *z);
+void ff_sbr_qmf_pre_shuffle_sse2(float *z);
 
 av_cold void ff_sbrdsp_init_x86(SBRDSPContext *s)
 {
@@ -46,5 +48,10 @@ av_cold void ff_sbrdsp_init_x86(SBRDSPContext *s)
         s->hf_gen     = ff_sbr_hf_gen_sse;
         s->qmf_post_shuffle = ff_sbr_qmf_post_shuffle_sse;
         s->neg_odd_64 = ff_sbr_neg_odd_64_sse;
+        s->qmf_pre_shuffle  = ff_sbr_qmf_pre_shuffle_sse;
+    }
+
+    if (EXTERNAL_SSE2(mm_flags)) {
+        s->qmf_pre_shuffle  = ff_sbr_qmf_pre_shuffle_sse2;
     }
 }
-- 
1.8.0.msysgit.0